EM78P447红外遥控电动机 -

;***********************************************************************
; 红外遥控电动机.dt
;***********************************************************************

本文引用地址: http://www.21ic.com/app/mcu/201806/761628.htm

PORT5 == 0x05 ;定义端口5，6
PORT6 == 0x06
;-----------------------------------------------------------------------
IOCE == 0x0E ;定义WDT控制寄存器IOCE
;-----------------------------------------------------------------------
BUFFER == 12 ;定义暂存器BUFFER，存放当前输出
DLY1 == 13 ;定义延时置数单元DLY1，DLY2，DLY3
DLY2 == 14
DLY3 == 15
;-----------------------------------------------------------------------
ORG 0x00
INIT: MOV A,@0x0FF ;设定P5口全部为输入
IOW PORT5
MOV A,@0x00 ;设定P6口全部为输出
IOW PORT6
MOV A,@0X11
IOW IOCE ;关闭看门狗功能
MOV A,@00000000B
MOV BUFFER,A ;停止电机运行
MOV PORT6,A
;-----------------------------------------------------------------------
MAIN: NOP
IRTEST0: JBC PORT5,0 ;检查红外按键0（前进，保持）
JMP IRTEST1
JMP IR0
IRTEST1: JBC PORT5,1 ;检查红外按键1（后退，保持）
JMP IRTEST2
JMP IR1
IRTEST2: JBC PORT5,2 ;检查红外按键2（自转，保持）
JMP IRTEST3
JMP IR2
IRTEST3: JBC PORT5,3 ;检查红外按键3（右转，点动）
JMP IRTEST4
JMP IR3
IRTEST4: JBC PORT5,4 ;检查红外按键4（左转，点动）
JMP IRTEST5
JMP IR4
IRTEST5: JBC PORT5,5 ;检查红外按键5（停止）
JMP KEEPRUN ;无键按入，保持原运行状态
JMP IR5
;-----------------------------------------------------------------------
IR0: CALL KEYDELAY ;电机M1正转，M2正转，保持
IR00: MOV A,@0B00000101 ;输出编码
MOV BUFFER,A ;送暂存器保存
MOV PORT6,A ;Port6口输出
IR000: JBS PORT5,0 ;检查按键是否已释放
JMP IR000 ;未释放，等待
JMP IRTEST0 ;已释放，跳转去检查按键是否有按下
IR1: CALL KEYDELAY ;电机M1仃转，M2正转，点动
IR01: MOV A,@0B00000100
MOV PORT6,A
CALL TURNDELAY
MOV A,BUFFER
MOV PORT6,A
IR010: JBS PORT5,1
JMP IR010
JMP IRTEST0
IR2: CALL KEYDELAY ;电机M1正转，M2反转，保持
IR02: MOV A,@0B00001001
MOV BUFFER,A
MOV PORT6,A
IR020: JBS PORT5,2
JMP IR020
JMP IRTEST0
IR3: CALL KEYDELAY ;电机M1正转，M2仃转，点动
IR03: MOV A,@0B00000001
MOV PORT6,A
CALL TURNDELAY
MOV A,BUFFER
MOV PORT6,A
IR030: JBS PORT5,3
JMP IR030
JMP IRTEST0
IR4: CALL KEYDELAY ;电机M1反转，M2反转，保持
IR04: MOV A,@0B00001010
MOV BUFFER,A
MOV PORT6,A
IR040: JBS PORT5,4
JMP IR040
JMP IRTEST0
IR5: CALL KEYDELAY ;电机M1，电机M2停转，保持
IR05: MOV A,@0B00000000
MOV BUFFER,A
MOV PORT6,A
IR050: JBS PORT5,4
JMP IR050
JMP IRTEST0
;-----------------------------------------------------------------------
KEEPRUN: MOV A,BUFFER ;保持原运行状态
MOV PORT6,A
JMP IRTEST0 ;继续检测红外按键
;-----------------------------------------------------------------------
KEYDELAY:MOV A,@1 ;按键去抖动延时10ms左右，需调整
MOV DLY3,A
CALL DELAY
RET
TURNDELAY:MOV A,@100 ;转弯延时500毫秒左右，需调整
MOV DLY3,A
CALL DELAY
RET
;-----------------------------------------------------------------------
DELAY: MOV A,@25 ;1*(DLY3)
MOV DLY2,A ;1*(DLY3)
INNER2: MOV A,@133 ;1*(DLY3)*(250)
MOV DLY1,A ;1*(DLY3)*(250)
INNER1: DJZ DLY1 ;1*(DLY3)*(250)*(133)
JMP INNER1 ;2*(DLY3)*(250)*(133)
DJZ DLY2 ;1*(DLY3)*(250)
JMP INNER2 ;2*(DLY3)*(250)
DJZ DLY3 ;1*(DLY3)
JMP DELAY ;2*(DLY3)
RET ;延时返回
EOP