51单片机演奏乐曲的程序 -

sbit SPK = P1^7 ;指定扬声器接口

本文引用地址: http://www.21ic.com/app/mcu/201806/764403.htm

ORG 0000H
LJMP START
ORG 000BH
LJMP T0_INT
ORG 001BH
LJMP T1_INT
;------------------------------------------------------------
B_ZQ_TAB: ;定时半周期初始值数据表（数据的意义可见前一篇博文）

DW 63625, 63833, 64019, 64104, 64260, 64400, 64524 ;低音区:1 2 3 4 5 6 7
DW 64580, 64685, 64778, 64820, 64898, 64968, 65030 ;中音区:1 2 3 4 5 6 7
DW 65058, 65110, 65157, 65178, 65218, 65252, 65283 ;高音区:1 2 3 4 5 6 7
DW 65297 ;超高音:1
;------------------------------------------------------------
MUSIC_TAB: ;自定义乐曲数据表
;一个音符有三个数字, 分别是音名、音区和时长（以1/8拍为单位）

DB 3, 1, 8 ;3, 中音, 8个1/8拍
DB 5, 1, 6 ;5, 中音, 6个1/8拍
DB 6, 1, 2 ;6, 中音, 2个1/8拍

DB 1, 2, 6 ;1, 高音, 6个1/8拍
DB 2, 2, 2 ;2, 高音, 2个1/8拍
DB 6, 1, 2 ;6, 中音, 2个1/8拍
DB 1, 2, 2 ;1, 高音, 2个1/8拍
DB 5, 1, 4 ;5, 中音, 4个1/8拍

DB 5, 2, 6
DB 1, 3, 2 ;1, 超高, 2个1/8拍
DB 6, 2, 2
DB 5, 2, 2
DB 3, 2, 2
DB 5, 2, 2
DB 2, 2, 8

DB 0, 0, 8 ;休止, 8个1/8拍
;------------------------------------------
DB 5, 1, 8
DB 3, 1, 4
DB 5, 1, 4
DB 1, 2, 16 ;1, 高音, 16个1/8拍
DB 6, 1, 8 ;6, 中音, 8个1/8拍
DB 1, 2, 4 ;1, 高音, 4个1/8拍
DB 6, 1, 4 ;6, 中音, 4个1/8拍
DB 5, 1, 16 ;5, 中音, 16个1/8拍

DB 0, 0, 8 ;休止, 8个1/8拍

DB 0, 0, 0 ;乐曲结束标记
;============================================================
START:
MOV TMOD, #11H ;T1, T0皆为定时方式1
MOV TL1, #(65536-1000) MOD 256
MOV TH1, #(65536-1000) / 256 ;1ms@12MHz
SETB TR1
MOV IE, #10001010B
MOV IP, #00000010B
MOV 42H, #200 ;以200ms，为1/8拍
MOV DPTR, #MUSIC_TAB
;-------------------下面是从自定义乐曲数据表中读取三个字节
M_LOOP:
CLR A
MOVC A, @A+DPTR
MOV R2, A
INC DPTR
CLR A
MOVC A, @A+DPTR
MOV B, A
INC DPTR
CLR A
MOVC A, @A+DPTR
JZ START
;-------------------下面是根据前两个字节，在半周期初值表中找
MOV R3, A
INC DPTR
MOV 44H, DPL
MOV 45H, DPH
MOV A, #7
MUL AB
ADD A, R2
JZ JI_SHI
DEC A
ADD A, ACC
MOV R2, A
MOV DPTR, #B_ZQ_TAB
MOVC A, @A+DPTR
MOV TH0, A
MOV 41H, A
MOV A, R2
INC A
MOVC A, @A+DPTR
MOV TL0, A
MOV 40H, A
SETB TR0
JI_SHI:
MOV 42H, #100
MOV 43H, #0
MOV A, R3 ;用第三个字节控制时长
CJNE A, 43H, $
CLR TR0
SETB SPK
MOV DPL, 44H
MOV DPH, 45H
SJMP M_LOOP
;------------------------------------------------------------
T0_INT:
MOV TL0, 40H
MOV TH0, 41H
CPL SPK
RETI
;------------------------------------------------------------
T1_INT:
MOV TL1, #(65536-1000) MOD 256
MOV TH1, #(65536-1000) / 256 ;1ms@12MHz
DJNZ 42H, T1_END
MOV 42H, #200 ;此数值越大，节奏越慢
INC 43H ;43H单元每隔200ms，加一次一
T1_END:
RETI
;============================================================